BB'S IRISH TRADITIONAL TUNE LIBRARY
"Johnny O'Leary of Sliabh Luachra"  (ed. Terry Moylan; Dublin 1994)
Tunes J - Y 
======================================
folder 31 index by name
folder 31 index by tune type
======================================
General Instructions for ITTL ABC files

======================================
The originals of the edited tunes in this folder are in file called
31-sv.rtf. They share the X: number with the arranged versions, so 
that number can be used for search purposes.

======================================

X:31102
T:JACK CONNELL'S POLKA 
Z:ABC/arr. BB
B:JOL.267
Q:1/4=120
L:1/8
M:2/4
R:polka
K:G
G2 Bd|gf/g/ ed|G2 Bd|eB dc/d/|
GB/G/ Bd|gf/g/ ed|e/f/g/e/ dB|DE G2 :|
B2 BA|dB ed|B2 Bd|B/A/G/B/ A2|
B2-BA|dB ed|e/f/g/e/ dB|DE G2 :|

%%%

X:31103
T:JACK REGAN'S SLIDE 
Z:ABC/arr. BB
B:JOL.238
Q:1/4=180
L:1/8
M:12/8
R:slide
K:Bm
F2B BAB d2e faf|e2e efe c2e a3 |
F2B BAB d2e faf|e2d B2A B3 B3 :|
f3 efe ded cdc|BAB edB AFE EDE|
FBB BAB d2e faf|e2d B2A B3 B3 :|

%%%

X:31106
T:JACK SWEENEY'S JIG 
Z:ABC/arr. BB
B:JOL.183
Q:1/4=160
L:1/8
M:6/8
R:jig
K:D
eaga fdf|dcd A2A|dcd fdd|gfg efg|
aga fdf|dcd A2A|Bcd gec|edc d2 :|
%
B|A2d fdd|add fdd|Add fdd|gfg ecB|
Add fdd|add fdd|Add efg|fdc d2c|
Add fdd|add fdd|Add fdf|gfg efg|
aga fdf|dcd A2A|B2d gec|edc d3|]

%%%

X:31104
T:JACK SWEENEY'S POLKA (1) 
Z:ABC/arr. BB
Q:1/4=120
B:JOL.199
L:1/8
M:2/4
R:polka
K:D
E|DE FG|AG AB|=c/B/A dF|G2 GF/G/ |
EF GA|cB cB|A2 c/B/A/F/|D2 D :|
B|A2 AG/A/|B2 B/A/B|c2 c/B/A|F2 F/B/c/B/|
A2-A/G/A/G/|BB-B/A/B|ce Bc| d2 d :|

%%%

X:31105
T:JACK SWEENEY'S POLKA (2) 
Z:ABC/arr. BB
B:JOL.25
%A Kerry version of "Mairi's Wedding"
Q:1/4=120
L:1/8
M:2/4
R:polka
K:A
A/F/|E2 EF|AB c2|BA FA|cB ce |
E2 EF|AB ce/c/| BA FA|E2 E :|
d|e2 ef|ed cd/c/| BA FA| cB cB/c/|
e>d ef|ed cd/c/| BA FA|E2 E :|

%%%

X:31107
T:JER O'CONNELL'S POLKA 
Z:ABC/arr. BB
B:JOL.215
Q:1/4=120
L:1/8
M:2/4
R:polka
K:D
AD ED|FA dc/d/| cA B/A/G | EF GF/G/ |
AD ED|FA dc/d/|cA GE|F/E/D D2 :|
Ad de|fg/f/ ed|cA AB|B/c/d ef/e/|
Ad de|fd e/f/e/d/|cA GE|ED D2 :|

%%%

X:31108
T:JER THE RIGGER (hornpipe)  
Z:ABC/arr. BB
B:JOL.113
%This tune is also played as a polka.
Q:1/4=150
L:1/8
M:4/4
R:hornpipe
K:A
%swing .25
d|e2A2 e2A2|efed cdBc|Addc def=g|a3f e4|
e2A2 e2A2|efed c2A2|d2fd c2ec|BABd A3 :|
g|a2ea fece|a2e=g fecB|Addc def=g|a3f e3f|
a2ae fece|a2e=g fecB|d2fd c2ec|BABd A3 :|

%%%

X:31109
T:JEROME BURKE'S POLKA 
Z:ABC/arr. BB
B:JOL.298
Q:1/4=120
L:1/8
M:2/4
R:polka
K:D
DF AB/c/|dc BA|BA/B/ EF|GE F/G/F/E/|
DF AB/c/|dc BA|Be Bc|d2 d2 :|
f2 fe/f/|gf ed|e>d e>e|fd BA|
Af fe/f/|gf ed|ce Bc|d2 d2 :|

%%%

X:31110
T:JIM KEEFFE'S POLKA 
Z:ABC/arr. BB
B:JOL.188
Q:1/4=120
L:1/8
M:2/4
R:polka
K:A
ea c/d/c/B/ | Ac EF/E/ | cB Bc/e/ | fe ce |
a2 c/d/c/B/|Ac EF/E/|cB Bc/B/|A2 A2 :|
c2 Bc/e/|fe ce|ce/c/ Bc/e/|fe ce|
a2 c/d/c/B/|Ac EF/E/|cB c/d/c/B/|A2 A2 :|

%%%

X:31115
T:JIMMY DOYLE'S FAVORITE (jig) 
Z:ABC/arr. BB
B:JOL.259
Q:1/4=160
L:1/8
M:6/8
R:jig
K:G
E|Fdd cAA|dcA A2G|FdF cAA|dcA G2G|
Fdd cAA|dcd efg|faf ged|cAF G2:|
E|A2A fdd|cAB cAB|A2A fed|dcA G3|
A3 fed|cAB Bde|fgf ded|cAF G2:|

%%%

X:31112
T:JIMMY DOYLE'S POLKA (1) 
Z:ABC/arr. BB
B:JOL.051
Q:1/4=120
L:1/8
M:2/4
R:polka
K:G
A|Bd dg/e/|dB BA/B/|d>B AB|d/e/d/B/ G2|
Bd dg/e/|dB BA/B/|dG BA|AGG :|
A|Bd g2|fe e/f/e/^d/|ed dB/d/|ed Bd|
dB/d/ gf/g/|fg/f/ e/f/g/e/|dB BA|BGG :|

%%%

X:31113
T:JIMMY DOYLE'S POLKA (2) 
Z:ABC/arr. BB
B:JOL.069
Q:1/4=120
L:1/8
M:2/4
R:polka
K:D
FA D>E|FA BA|FA DE|FG/F/ ED/E/|
FG/A/ D>E|FA BA|FG/A/ Bc|ed d2|
FG/A/ D>E|FA BA|FA D>E|FE ED/E/|
FA D>E|FA BA|FA/F/ Bc|ed d2||
D>A BA|dc/d/ BA|FA DE|FE EF/E/|
DF/A/ BA|dA BA|FA Bc|ed d2 :|

%%%

X:31114
T:JIMMY DOYLE'S POLKA (3) 
Z:ABC/arr. BB
B:JOL.249
Q:1/4=120
L:1/8
M:2/4
R:polka
K:D
d2 ee/d/|ce A2|dA/d/ ef|ge f/g/f/e/|
d2 e/f/e/d/|ce AB/A/|a>f ge|d2 dB/c/|
d2 e/f/e/d/|cA AB/c/|dc/d/ ef|g2 f/g/f/e/|
d2 e/f/e/d/|ce AB/A/|af/a/ ge|d2 d2||
|:f2 g/f/d|g2 a/g/e|f2 fe/f/|eA BA|
ff/e/ fd/f/|g>f ge|fa ge|d2 d2 :|

%%%

X:31111
T:JIMMY DOYLE'S SLIDE 
Z:ABC/arr. BB
B:JOL.108
Q:1/4=180
L:1/8
M:12/8
R:slide
K:D
fdB BAB g2g f2e|d2B BAB e2e efe|
dfd BAB g2e f2e|d2B BAB A3 A3 :|
faf e2e faf efe|d2B BAB e2e ede|
faf e2e faf efe|d2B BAB A3 A3 :|

%%%

X:31116
T:JOE CONWAY'S JIG 
Z:ABC/arr. BB
B:JOL.026
Q:1/4=160
L:1/8
M:6/8
R:jig
K:Ador
g|edA G3|B2A Bdd|edA G2G|BFG gfg|
edA G2A|Bdd Bdd|eag edB|BAA A2 :|
d|e2f ged|eaf ged|e3 ged|efg a2a|
aba age|ged B2d|eag edB|BAA A2 :|

%%%

X:31117
T:JOHN CLIFFORD'S POLKA (1) 
Z:ABC/arr. BB
B:JOL.109
Q:1/4=120
L:1/8
M:2/4
R:polka
K:G
G>A Bd|ef gf/g/|ed Bd|e/f/e/d/ BA |
G>A Bd|ef gf/g/|ed B/c/B/A/|G2 G2 :|
g>f ed|ef gf/g/|ed Bd|e/f/e/d/ Bd|
g>f ed|ef gf/g/|ed B/c/B/A/|G2 G2 :|

%%%

X:31118
T:JOHN CLIFFORD'S POLKA (2) 
Z:ABC/arr. BB
B:JOL.339
Q:1/4=120
L:1/8
M:2/4
R:polka
K:D
A|: d>c df|B2 B2|c/B/A/B/ ce|A2 A2 |
B/c/d ef|g2 gf/g/|1 fe fd|a2 a>a :|\
[2 fe af|d2 d||
|:B|d2 f/e/d/B/|AF f/e/f|Be e/d/e|Ad dA|
d2 f/e/d/B/|AF f/e/f|ge/d/ ce|d2 d :|

%%%

X:31119
T:JOHN COLLINS' FANCY (polka)  
Z:ABC/arr. BB
B:JOL.262
Q:1/4=120
L:1/8
M:2/4
R:polka
K:D
Ad cB|BA F2|AG EF/E/|BA FA |
Ad cB|c/B/A FG/F/|AG/A/ Bc|d2 d2 :|
A2 AB|de f2|ed Be|ed/B/ A2|
A2 AB|de fa/f/|ed BA|d2 d2 :|

%%%

X:31120
T:JOHN KELLY'S SLIDE  
Z:ABC/arr. BB
B:JOL.287
Q:1/4=180
M:12/8
L:1/8
R:slide
K:D
e|f2A AFA B2A d2d|c2B BAB g2g f2e|
f2A ABA B2A d2d|cec B2c d3 d2 :|
f|g2g gfe f2f fed|Bee efe d2B B2A|
g2g gfe f2e fed|Bee efa b3 a2 :|

%%%

X:31121
T:JOHN WALSH'S POLKA (1) 
Z:ABC/arr. BB
B:JOL.260
Q:1/4=120
L:1/8
M:2/4
R:polka
K:G
G>A BA|GE F/E/D|B,2 ED|B,D ED|
GF/G/ BA|GE ED|B,D ED|G2 G2 :|
g2 fg|ag gf/e/|dB c/B/A|GA Bd|
ga/g/ fg|ag gf/e/|dB c/B/A|G2 G2 :|

%%%

X:31122
T:JOHN WALSH'S POLKA (2) 
Z:ABC/arr. BB
B:JOL.261
Q:1/4=120
L:1/8
M:2/4
R:polka
K:G
P:I
F|G>A BA | GE ED | G>A BA | GB d^c/d/ |
G>A BA|GE F/E/D|G>A BA|G2 G :|
P:II
e|dg gf/e/|dB BA/B/|AB c/^c/d|ed Bc/B/|
dg gf/e/|dB BA/B/|AB c/B/A|G2 G :|
P:III
e|dg gb|ag gd|e/f/g ed|dB B>c|
dg gb|ag gd|e/f/g ed|g2 g :|
P:IV
c|dB B/c/B/A/|GB Bc/B/|AB B/c/d/f/|ed BB/A/|
GB B/c/B/A/|GB BA/B/|AB cA|G2 G :|

%%%

X:31123
T:JOHNNY COPE (hornpipe)  
Z:ABC/arr. BB
B:JOL.285
%"That's Pádraig's version of that now. Myself and Julia
%[Clifford] played that hundreds of times together." [< JOL]
Q:1/4=150
%simplified; source version here
M:4/4
L:1/8
R:hornpipe
K:Ador
%swing .25
P:I
AG|EAAG A2Bd|efed B2AG|EGGF GEDE|G2BG AGFG|
A3G A2 Bd|e2A2 BAG2|egfa gedB|BAAG A3G|
EAAG ABcd|eged B2AG|EGGF GEDE|G2BG AGFG|
A3G A2Bd|e2A2 BAG2|egfa gedB|BAAG A2||
P:II
|:AB|c2cd c2Bd|cdef gedB|cBAc e3d|cdec dBGB|
c2cd c2Bd|cdef gedg|eaag efdB|BAAG A2:|
P:III
|:AB|cBcB AGAG|ABcd e2dc|BG~G2 dG~G2|BdeB dBGB|
c3B A2 AG|ABcd e2dg|eaag efdB|BAAG A2 :|
P:IV
|:af|e2de a2ga|b2ab g2ge|dggf gaba|g2bg aged|
e2de a2ga|b2ab g2ge|d2ef gedB|BAAB A2 :|
P:V
|:eg|e2de fedg|edeg fedB|d3c dBAB|d2fd edBd|
e2de fedf|edeg fedB|Bdfd efdB|BAAB A2 :|
P:VI
|:eg|a2e2 edef|a2e2 edeg|f2d2 dcde|f2d2 d2eg|
a2eg fede|eaag fedB|ABdf efdB|1BAAB A2:|

%%%

X:31124
T:JOHNNY MICK DINNY'S (slide)  
Z:ABC/arr. BB
B:JOL.095
Q:1/4=180
%simplified; source version here
L:1/8
M:12/8
R:slide
K:Ador
B|A2G AGE c2B c2d|efg edB g3-ged |
eaf g2e dBA G2A|BeB dBG A2B c2:|
d|e2a age dgf ged|eag agf g g2-ged |
eaa g2e dBA GAB|c2e d2B A3 A2 :|

%%%

X:31125
T:JOHNNY THE TAILOR'S FANCY (slide)  
% aka Quarry Cross Slide #1
Z:ABC/arr. BB
B:JOL.102
Q:1/4=180
L:1/8
M:12/8
R:slide
K:G
A|B3 B2A Bcd edB|G2D A2D ABA GED |
DBD BBA GBd edB|A2F DFA G3G2 :|
B/c/|d2g gfe d2B GBd|e2a a2g faa def|
gfg gfe ded Bcd|efg agf g3 g2 :|

%%%

X:31126
T:JOHNNY WHEN YOU DIE (reel)  
Z:ABC/arr. BB
%irish_rolls_on
B:JOL.165
Q:1/4=180
M:4/4
L:1/8
R:reel
K:G
e2dB eBdB|ABGA BA A2|e2dB eBdB|ABGA BG G2|
ezdB eBdB|A2 GA BA ~A2|GB ~B2 dB ~B2|A2 GA BG G2||
g2fg efde|gzfg ea a2|gzfg efdB|A2 GA BG G2|
g2fg efde|gbag ea a2|gbag efdB|A2GA BG G2|]

%%%

X:31127
T:JULIA CLIFFORD'S JIG 
Z:ABC/arr. BB
B:JOL.252
Q:1/4=160
L:1/8
M:6/8
R:jig
K:A
e|fdf afe|faf f2e|faf ecA|BcB Bce|
fdf afe|faf afe|faf ece|ABA A2 :|
B|cBc ece|faf ece|a2f ecA|Bcc BAB|
c2c ece|faf ece|faf ece|ABA A2 :|

%%%

X:31128
T:JULIA CLIFFORD'S SLIDE 
%This is the well-loved session tune better known as 
%"Denis Murphy's"
Z:ABC/arr. BB
B:JOL.133
Q:1/4=180
L:1/8
M:12/8
R:slide
K:D
B|A2D FED F2A A2f|gfe fed e2d BAd|
A2D FED F2A A2e|1 faf ege d3 d2 :|
[2 faf ege ded ABc|: d2e f2f gfe f2f|
gfe fed e2d B2A|d2e fdf gfe f2f|
[1 faf ege d3 d3 :|2 faf ege d3 d3|]

%%%

X:31129
T:KAISER (slide) 
%aka Going to the Well for Water
Z:ABC/arr. BB
B:JOL.134
Q:1/4=180
L:1/8
M:12/8
R:slide
K:D
A2f A2f A2f fed|B2g B2g B2g gfe |
c2e A2A AGA a2f|gfe cde d3 d3 :|
f3 fed e3 gfe|d3 fed c3 cBA|
G2B G2B F2A F2A|E2F e2d cBc d3 :|

%%%

X:31130
T:KENMARE POLKA
Z:ABC/arr. BB
B:JOL.297
Q:1/4=120
L:1/8
M:2/4
R:polka
K:G
D| GF/G/ AB|c/B/A dB|GB/G/ AB|c/B/A FD|
G2 AB|c/B/A de|fd c/B/A|BG G :|
e|gf/g/ ag|fd de|fd de|fd ef|
gf/g/ ag|fd de|fe/d/ cA|AG G :|

%%%

X:31131
T:KERRY COW (polka) 
Z:ABC/arr. BB
B:JOL.342
Q:1/4=120
L:1/8
M:2/4
R:polka
K:D
dc/d/ fd|cA AE/A/|BG GA/G/|BA AF/A/|
de fd|cA AF/A/|GB AF|D2 D2 :|
A>B AG|FA dE/F/|G>F GF|EF GF/G/|
A>G AG|Ad dc/d/|cA G/A/G/E/|D2 D2 :|

%%%

X:31133
T:KILCUMMIN LASS (polka)  
Z:ABC/arr. BB
B:JOL.324
Q:1/4=120
L:1/8
M:2/4
R:polka
K:D
AB c/B/A | ed/e/ cB | AB c/B/A | f2 fd/B/ |
AB c/B/A|eA cB/c/|AB cA|d2 d2 :|
fe/f/ ed|fe/f/ ed/e/|A2 c/B/A|g2 g2|
fg/f/ ed|fg/f/ ed/e/|AB ce|d2 d2 :|

%%%

X:31132
T:KILCUMMIN SLIDE 
Z:ABC/arr. BB
Q:1/4=180
B:JOL.091
L:1/8
M:12/8
R:slide
K:G
e|gfg ded B2d G2B|AGA DFA G2A def|
ged ded B2G GFG|AGA DFA G3 G2 :|
B|d2g gfg b2b bag|a2g e2f gfg edB|
Agg gfg b2b bag|faa e2f g3 g2 :|

%%%

X:31134
T:KISHKEAM LASSES (slide)
Z:ABC/arr. BB
B:JOL.184
Q:1/4=180
L:1/8
M:12/8
R:slide
K:D
B|d2f e2d c2e EFG | AGA BAG F2A D3 |
dcd e2d cBc EFG|A2F GFE D3 D2 :|
e|f2d fdc d2f a2f|e2A ABA Bcd ede|
f2a d2c d2f a2f|ede ABc d3 d2 :|

%%%

X:31135
T:KITTY'S WEDDING (jig) 
Z:ABC/arr. BB
B:JOL.193 
%This is in the "Ship in Full Sail" family. Source key
%is A, but too many high C's for comfort!
Q:1/4=160
L:1/8
M:6/8
R:jig
K:G 
P:I
GE|DzG BAG|dcd GBd|dge dBG|ABA AGE|
DzG BAG|dcd GBd|dge dBA|AGF G2E|
D2G BAG|d2d GBd|g2e dBG|ABA AGE|
D2G BAG|dcd GBd|g2e dBA|BGG G2d||
P:II
d2g agg|aga bge|d2d bgg|aba age|
d2d bgg|aga bge|dge dBG|ABA G3 :|
P:III
d2e dBG|e2d ege|deB dBG|ABG ABc|
ded dBG|e2d ege|dBB AGA|BGF G3 :|
P:IV
dBd GBd|dBd g2e|dBA G2a|bge g2e|
edB G2d|dBd g2a|bab bag|1 "thru"gee egg :|
[2 "^coda" ged Bef|g3-g3|]

%%%

X:31136
T:KNOCKNABOUL POLKA 
Z:ABC/arr. BB
B:JOL.281
Q:1/4=120
L:1/8
M:2/4
R:polka
K:G
P:I
B>A|: GB B/c/B/A/ | GB c/B/A/B/ | FA AB/A/ | FA D2 |
GB B/c/B/A/|GB dg|fd cA|1 G2 B/c/B/A/ :|2 G2 G||
P:II
d/f/|g2 a/g/f|ga a>g|fd de|fg ad/a/|g>f gf|
gb d/b/a/g/|fd cA|1 G2-G:|2 G2 ||
P:III
zG|B2 cB/c/|d/e/d/c/ AG|F/G/F/E/ FG|AB c/B/A|
B2 cB/c/|dc AG|fd cA|1 G2:|2 G2G2-|G4|]

%%%

X:31137
T:KNOCKNABOUL SLIDE 
Z:ABC/arr. BB
B:JOL.289
Q:1/4=180
L:1/8
M:12/8
R:slide
K:G
D| G2B d^cd e2f g2g | f2e d2B cBA B2A |
G2B d^cd e2f gfe|d2B ABA G3 G2 :|
A|BcB ABA G2G GAB|c3 B2G A2G E2D|
B2B ABA GAG gfe|d2B ABA G3 G2 :|

%%%

X:31138
T:KNOCKNAGREE POLKA  
Z:ABC/arr. BB
B:JOL.027
Q:1/4=120
L:1/8
M:2/4
R:polka
K:A 
C>E FE|CE EF/E/|CE Ac|B/c/B/A/ FA|
CE FE|CE EF/E/|ed/e/ Ac|Bc/B/ A2 :|
ef/e/ Ac/e/|fe f/g/a/f/|ec/e/ fc|ec Bc|
ef/e/ Ac/e/|fe f/g/a/f/|ec BA/B/|cA A2 :|

%%%

X:31139
T:LACKAGH CROSS POLKA 
Z:ABC/arr. BB
B:JOL.220
Q:1/4=120
L:1/8
M:2/4
R:polka
K:D
D|EF/G/ FE|F/E/D FA|EF/G/ FE|F2 FA|
EF/G/ FE|FD FA|BA B/c/d|e2e :|
|:f/e/|dA FA|DA FA|c/d/c/B/ GB|A2 A2|
dA FA|DA FA|BA B/c/d|e2 e :|

%%%

X:31140
T:LIGHTHOUSE POLKA 
Z:ABC/arr. BB
Q:1/4=120
L:1/8
M:2/4
B:JOL.159
R:polka
K:D
e|fd Ad|fd Ad|fd/B/ AF|E2 Eg|
fd Ad|fd A>d|fd/B/ AF/A/|D2D :|
E|F/E/D FA|de f>e|dB AF|E2 E2|
FD FA|de f/g/f/e/|dB AF|D2D :|

%%%

X:31141
T:LIL'S FANCY POLKA 
Z:ABC/arr. BB
B:JOL.194
Q:1/4=120
L:1/8
M:2/4
R:polka
K:D
P:I
d2 cd/c/|BA FA|EF/E/ FE|BA FA|
dc/d/ cB/c/|BA FA|EF/E/ FE|F/E/D D2 :|
P:II
EF/G/ EF|BA FA|EF/G/ FE|BA FA|
dc/d/ cB/c/|BA FA|EF/G/ FE|F/E/D D2|
EF/G/ FE|BA FA|BE EF/A/|BA FA|
dc/d/ cB/c/|BA FA|EF/G/ FE|F/E/D D2|]

%%%

X:31142
T:LITTLE ARK* (reel) 
Z:ABC/arr. BB
B:JOL.004 [unnamed]
%My Clare name for a "gan ainm" Kerry tune!
Q:1/4=180
L:1/8
M:4/4
R:reel
K:G
G2GB dedB|cABG AGEB|G2GB d2Bd|egfa gedB|
G2GB dedB|cABG AGEF|G2GB d2Bd|egfa g4 ||
gabg aged|egge dBB2|gabg aged|egfa g4|
gabg aged|efge dBBA|G2GB d2Bd|egfa gedB||\
"^coda"G4z4|]

%%%

X:31143
T:LONESOME JIG  
%One of the "Bill the Weaver's" family
Z:ABC/arr. BB
B:JOL.122
Q:1/4=180
L:1/8
M:12/8
R:slide
K:D
F3 EDE F2E D2E|F2D EFA d2e fdB|
F3 EDE F2E D2B|AFD EFA B3 d3 :|
ABd e2f d2c B2A|ABd efe d2c B2A|
ABd ede fec dBA|FED EFA B2c d2d :|

%%%

X:31145
T:MATT DALY'S SLIDE 
Z:ABC/arr. BB
B:JOL.291
Q:1/4=180
L:1/8
M:12/8
R:slide
K:A
P:I
B|A2F E2F A2B c2c|BAB cBA B2A F2B|
A2F E2F A2B c2d|e2c BcB A3 A2 :|
P:II
f/g/|a3 a2e f2g a2f|e2c BAB c2A F3|
a3 a2e f2g a2f|e2c BcB A3 A3|
a3 a2e f2g a2f|e2c BAB c2A F2B|
A2F E2F A2B cBc|e2c BcB A3 A3|]

%%%

X:31146
T:MATT TEAHAN'S DELIGHT  
Z:ABC/arr. BB
B:JOL.274
Q:1/4=160
L:1/8
M:6/8
R:jig
K:Ador
f|eAA eAA|BAB GBd|eAA eAA|def gfg|
eAA eAA|BAB GBd|dB/c/d edB|BAG A2 :|
f|a2a bge|aga bge|dBB gBB|def gfg|
[1 aAA bge|aga bge|dBB gBB|BAG A2:|
[2 age edB|dBA GAB|dBd gdB|BAG A3|]

%%%

X:31147
T:MAULYKEAVANE RAMBLER (slide)  
Z:ABC/arr. BB
B:JOL.019
%Pronounced mol-ly-KEV=in
Q:1/4=180
L:1/8
M:12/8
R:slide
K:D
F2B AGA F2B AGA|Bcd e2d c2d BBA |
F2B AGA F2B AGA|Bcd efe B2c d3 :|
f3 f2e d2c B2A|Bcd e2d c2e B2A|
fgf f2e d2c B2A|Bcd efe B2c d3 :|

%%%

X:31148
T:MAURICE MANLEY'S (slide)  
Z:ABC/arr. BB
B:JOL.009
Q:1/4=180
L:1/8
M:12/8
R:slide
K:Ador
G|EFG A2B c2d e2g|G2E EDE G2E D3 |
EFG A2B c2d e2f|gfe d2e B2A A2 :|
g|a3 a2b a2g e2f|gfg gfe def gfg|
e2a a2b a2g e2f|gfg ded B2A A2 :|

%%%

X:31149
T:McBAND'S (reel)  
Z:ABC/arr. BB
B:JOL.035
Q:1/4=180
L:1/8
M:4/4
R:reel
K:D
AG|FDAD dDAG|FDAF GBAG|FDAD BDAF|G2EF GBAG|
FDAD dDAG|FDAF GBAG|FDFA BGAF|G2EF GABc||
d2dc dAFA|d2 dc dfec|d2 dc dAFA|G2EF GABc|
d2ec dAFA|d2 dc df e2|fdec dA F2|G2EF GBAE||\
"^coda"D4z4|]

%%%

X:31150
T:MEENTOGUES LAD (slide)  
Z:ABC/arr. BB
B:JOL.024
Q:1/4=180
L:1/8
M:12/8
R:slide
K:G
E/F/|G2B d3 c2A g2e|d2B G2B A2B cBA|
G2B d2B cAc g2e|ded cBA G3 G2A|
G2B d2B cAc g2e|dcd GAB A2B cBA|
G2B d2B c2A g2e|ded cBA G3G2||
%
e|g3 g2e f2f d2d|ece g2e ded B2d|
G2B d2B cAc g2e|dfd cBA G3 Gf|
g3 g2e f2f eed|ece g2e d3 B2d|
G2B d2B cAc g2e|ded cBA G3-G3|]

%%%

X:31151
T:MERRILY KISS THE QUAKER (slide)  
Z:ABC/arr. BB
B:JOL.127
Q:1/4=180
L:1/8
M:12/8
R:slide
K:G
P:I
A|G2B D2G B2A AGE|GEE DEG A2B AGE|
G2B D2G BAA AGE|GAB D2E G3 G2 :|
P:II
|:A|G2B dBd edB d2B|G2B d2B A2B AGE|
G2B d2d edB d2B|GAB DED G3 G2 :|
P:III
|:A|G2B d2d ede g2e|dBA GBd e2f g2a|
ged BAB A2G EDE|GAB D2E G3 G2 :|

%%%

X:31152
T:MICK DUGGAN'S SLIDE 
Z:ABC/arr. BB
B:JOL.146
Q:1/4=180
L:1/8
M:12/8
R:slide
K:D
F2B A2A F2B AFA|Bcd e2d c2A B2A |
F2B A2A F2B AFA|Bcd efe B2c d3 :|
f3 gfe d2c B2A|Bcd e2d c2A B2G|
A2f f2e d2c B2A|Bcd efe B2c d3 :|

%%%

X:31153
T:MICK MAHONY'S SLIDE (1) 
%aka If I Had a Wife, Cullen Slide #1
Z:ABC/arr. BB
B:JOL.090
Q:1/4=180
L:1/8
M:12/8
R:slide
K:G
P:I
D|G2e dBG F2E E2G|F2A DEF G2A D3|
GBd dBG FAA EFG|F2A DEF G3 G2 :|
P:II
z|d3 g2B d2c A2B|cBA Afe d2B G2B|
d2B g2B d2c A2g|fed cBA G3 G2 :|
P:III
g|fed c3 e2d B2d|fed cBA G2A B2g|
fed c3 e2d B2d|fed cBA G3 G2 :|

%%%

X:31154
T:MICK MAHONY'S SLIDE (2) 
T:Cullen Slide #2
Z:ABC/arr. BB
%A close relative of the "Cat. . .Saucepan" family!
B:JOL.111
Q:1/4=180
L:1/8
M:12/8
R:slide
K:D
d2e f2f baf a2f|e2A cBA e2A cBA|
d2e f2f baf a2f|e2A cBA d3 d3 :|
d2e f2e dcd Bcd|e2A cBA e2A cBA|
d2e f2e dcd Bcd|e2A cBA d3 d3 :|

%%%

X:31155
T:MIKE BUCKLEY'S FAVORITE (polka)  
Z:ABC/arr. BB
B:JOL.256
Q:1/4=120
L:1/8
M:2/4
R:polka
K:A
P:I
ce/c/ BA|FE A2|cB Bc/B/|Ac/e/ fe|
ce/c/ BA|FA AB|cB/c/ ec|BA A2|
ce/c/ BA|FA AB|ce/c/ Bc/B/|Ac/e/ fe|
ce/c/ BA|FA AB|cB/c/ ec|BA A2||
P:II
|:ae fe|cA ed/e/|a2 fe|ce Bc/B/|
ae g/f/e|ce fe|c/d/e/c/ Be|cA A2 :|

%%%

X:31157
T:MIKE SULLIVAN'S HORNPIPE (1) 
Z:ABC/arr. BB
B:JOL.078
%A version of "Madame Bonaparte"
Q:1/4=150
%simplified; source version here
L:1/8
M:4/4
R:hornpipe
K:A
AB|c3B cecA|d2ec dfaA|BcAB ceaf|ecAc BAFA|
c2dB cecA|d2Bc dfaf|e2Ac BAFG|A2AG A2 :|
zd|efge aged|egfd ecA2|efg2 a3g|egfd edcB|
c2cB cecA|d2Bc dfaf|ecAc BAFG|A2 AG A2 :|

%%%

X:31157
T:MIKE SULLIVAN'S HORNPIPE (2) 
Z:ABC/arr. BB
B:JOL.254
Q:1/4=150
L:1/8
M:4/4
R:hornpipe
K:Edor % source key = Ador
D|E2FD E2FA|BdBA Bcd2|D3C D2 EF|GEFD EDB,C |
E2FD E2FA|B3A Bcdc|dedB A2 Bc|dBAG FEE :|
z|e3d e2 Bd|efgf edBc|d3c dBAc|dBeB dBA2|
e2ed edBd|efgf edBc|dcdB A2 Bc|dBAG FEE :|

%%%

X:31158
T:MIKEY BUCKLEY'S POLKA 
Z:ABC/arr. BB
B:JOL.148
Q:1/4=120
L:1/8
M:2/4
R:polka
K:D
E|FA dg|f/e/d/f/ e/d/B/A/|GB EF/E/|FA B/c/B/A/ |
FA dg|f/e/d/f/ e/B/d/B/|AF EF/E/|D2 D :|
g |f/e/d/f/ e/B/d/B/|Af dc/d/|cA G2|BA FD|
f/e/d/f/ e/B/d/B/|AF de/d/|cA GE|D2 D :|

%%%

X:31159
T:MIKIE DUGGAN'S POLKA 
Z:ABC/arr. BB
B:JOL.257
Q:1/4=120
L:1/8
M:2/4
R:polka
K:D
E|FD FA|de f/g/f/e/|dB AF|E2 E>G|
FD FA|de f/g/f/e/|dB AF|D2 D :|
e|fd Ad|fd Ad|fd/B/ AF|E2 E>d|
fd Ad|fd Ad|fd/B/ AF|D2 D :|

%%%

X:31160
T:MOLLY MYERS' JIG 
Z:ABC/arr. BB
B:JOL.330
Q:1/4=160
L:1/8
M:6/8
R:jig
K:G
B|dBG B2B|dBG ABA|GBd edB|ABd edB|
dBG B2B|dBG ABA|GBd efe|GAG G2 :|
A|B2A dcd|GBG BAG|B2d dBd|eAA AGA|
B2B dcd|GAG BAG|g2e dBA|G2F G2 :|

%%%

X:31161
T:MOUNTAINS OF POMEROY (march)
Z:ABC/arr. BB
B:JOL.331
Q:1/4=120
M:4/4
L:1/8
R:march
K:G
Bc|d>cde dcBA|G2A2 E2GE|D3E G2AB|c4 cABc|
d>cde dcBA|G2A2 E2GE|D3E G3A|G4-G2||
zA|B2A2 G2AB|c2d2 d2gf/e/|dcBA G2 AB|c4-cABc|
d>cde dcBA|G2A2 E2GE|D3E G3A|G4z4|]

%%%

X:31162
T:MUNSTER JIG 
Z:ABC/arr. BB
B:JOL.174
Q:1/4=160
L:1/8
M:6/8
R:jig
K:G
G3 AGA|Bcd gdB|GAB cBA|BGE GED|
G2G AGA|Bcd gdB|c2A BdB|AGF G2D|
G2B AGA|Bcd gdB|GAB cBA|BGE GDE|
G2G AGA|Bcd gdB|c2A BdB|AGG GBd ||
%
g3 efg|a2g fed|gfg efg|a2a def|
gfg agf|gfe fdB|c2A BdB|AGG GBd|
gfg efg|eag fed|gfg efg|a2a def|
gfg a2a|g2e fdB|c2A BdB|AGF HG3|]

%%%

X:31163
T:NED CONNOR'S (slide) 
%aka "Sleamhnán na Sróine" (Shrone Slide)
Z:ABC/arr. BB
B:JOL.116
Q:1/4=180
L:1/8
M:12/8
R:slide
K:A
AB|cec B2A F2A E2A|FAF E3 F2A E3|
cec B2A F2A E2F|A2B cBc A3 A2B|
c3 B2A FAF E3|F2A E3 E2A E3|
cec B2A F2A E2F|A2B cBc A3 A3||
%
|:A2B cBc ecc ecB|A2B cBA F2A E2B|
A2B cBc ecc ecB|A2B c2B A3 A3 :|

%%%

X:31164
T:NELL SULLIVAN'S (jig) 
Z:ABC/arr. BB
B:JOL.089
Q:1/4=160
L:1/8
M:6/8
R:jig
K:G
g|edB G2A|Bge dBd|edB AGA|BAG ABd|
edB G2A|Bge dBd|edB AGA|BGF G2:|
F|GBd e2d|edB dBc|dBA G2A|BAG ABA|
GBd e2g|edB dBA|GBG AGA|BGF G2:|

%%%

X:31165
T:NELLIE MAHONY'S (slide) 
%aka Bunratty Boys
Z:ABC/arr. BB
Q:1/4=180
B:JOL.043
L:1/8
M:12/8
R:slide
K:D
d|e3 efe d2f a2f|e2d efe d2A B2A|
Bed efe d2f a2f|efe gfe d3 d2 :|
B|A2a f2a A2a faf|efe gfe d2A B2A|
A3 f3 Aaa faf|efe gfe d3 d2 :|

%%%

X:31166
T:NEW-MOWN MEADOWS (reel)  
Z:ABC/arr. BB
B:JOL.152
Q:1/4=180
M:4/4
L:1/8
R:reel
K:D
A3d BABd|egfg edBd|e3A BAAB|dfed BAdB|
A3d BABd|egfg edBd|g3e fgfe|dfed Bdd2:|
|:a2fa bafg|a2fd edBA|a2fa bafe|dfed Bdd2|
a2da bafg|a2fd edBA|gage fgfe|dfed Bdd2 :|

%%%

X:31167
T:NICHOLAS McAULIFFE'S (slide)  
Z:ABC/arr. BB
B:JOL.244
Q:1/4=180
L:1/8
M:12/8
R:jig
K:G
E|D2G GFG ABc A2G|FGA DEF G2A Bcd |
DGF GFG ABc A2G|F2A DEF G3 G2 :|
A|B2B BGB c2B c2B|AGA ABA G2A Bcd|
DGF GFG ABc A2G|F2A DEF G3 G2 :|

%%%

X:31168
T:NIGHT AT THE FAIR (jig) 
Z:ABC/arr. BB
B:JOL.028
Q:1/4=160
L:1/8
M:6/8
R:jig
K:G
A|B2A GED|EGF G2A|BGG dGG|ABA AGA|
B2A GED|EGF G2A|BeB dBA|BGG G2 :|
d|efg eaa|egg ged|B2A dBG|ABA ABd|
efg eaa|egg ged|BeB dBA|BGG G2 :|

%%%

X:31169
T:NOONDAY FEAST (jig)
Z:ABC/arr. BB
B:JOL.263
Q:1/4=160
L:1/8
M:6/8
R:jig
K:G
B2A BGE|GBA GBd|gfe dBG|A2B AGA|
B2A BGE|GBA GBd|gfe dBA|BGG G3 :|
gfg efg|eag fed|gfg edB|BAG AGA|
B2A BGE|GBA GBd|gfe dBA|BGG G3 :|

%%%

X:31170
T:NORA CRIONA (slide)
Z:ABC/arr. BB
B:JOL.347
Q:1/4=180
L:1/8
M:12/8
R:slide
K:G
A|G3 G2A B2G d2B|G2F G2B A2c B2A|
GED G2A BGB dcB|Aee ede A2B cB:|
A|ded dcd B2G d3|dcd dcd A2B cBA|
dcd dcd B2G d2B|"thru"A2e ede A2B cB :|
"^coda"A|G6z6|]

%%%

X:31171
T:O'KEEFFE'S SPEED THE PLOUGH (1) (reel)  
Z:ABC/arr. BB
B:JOL.093
Q:1/4=180
L:1/8
M:C
R:reel
K:D
d3A BAFA|A2BA FADE|FAAF G3A|Bcde fgfe|
defe dAFG|ABAF EFDE|FAAF G3B|ABde fdd2 :|
adBd afdf|g2fg eBB2|fgag fedB|ABde fddc|
adBd afdf|g2fg edBG|FAAF GBBG|ABde fdd2 :|

%%%

X:31172
T:O'KEEFFE'S SPEED THE PLOUGH (2) (reel)  
Z:ABC/arr. BB
B:JOL.150
%aka 'Charlie Mulvihill's'. One of the "Doon Reel" family.
Q:1/4=180
M:4/4
L:1/8
R:reel
K:D
c|d3A BAFG|A2 FA EFDE|FAAF G3B|ABde fgfe|
defe dBAG|AFF2 EFDE|F2AF GBdB|ABde fdd :|
e|faag afdf|g2 fg edBA|faag afdB|ABde fd d2|
afbf afdf|g2 fg edBA|F2AF G3B|ABde fdd :|

%%%

X:31173
T:O'KEEFFE'S WALTZ 
Z:ABC/arr. BB
B:JOL.271
Q:1/4=150
L:1/8
M:3/4
R:waltz
K:G
DE |G4G2 | G2A2B2 | A4G2 | A4 BA |
G2G3G | g2 (3fgf e2 | d2B2G2 | A2B2 (3ABA |
G4G2 | G2A2B2 | A4 E2 | A3B (3cBA |
G2E2G2 | A2B2A2 | G6 |G4 :|
%
d2|g2f2g2 | a2g2a2 | b2a2g2 | (3efd (3efe d2|
g4-gf/g/| a2g2a2 | b2a2g2 | e4g2 |
f2e2d2 | e2f2e2 | d2B2G2 | A2B2A2 |
G2E2G2 | A2B2A2 |1 "thru"G6 |G4 :|
[2 "^coda"G3 DEF |HG6|]

%%%

X:31175
T:O'SULLIVAN'S FANCY POLKA 
Z:ABC/arr. BB
B:JOL.096
Q:1/4=120
L:1/8
M:2/4
R:polka
K:D
AD FG|A>G AB|=c/B/A GA/G/|EF GF/G/|
AD FG|A>G AB|=c/B/A GE|F/E/D D2 :|
Ad de|fg/f/ ed|c>A AB|cd ef/e/|
A2 de|f2 ed|cA GE|ED D2 :|

%%%

X:31174
T:O'SULLIVAN'S POLKA 
Z:ABC/arr. BB
B:JOL.008
Q:1/4=120
L:1/8
M:2/4
R:polka
K:G
fg/f/ df|e/f/e/d/ BA|BB/A/ GE|BB/A/ GE|
fg/f/ df|e/f/e/d/ BA|BB/A/ G/A/B/d/|ag g2 :|
BB/A/ G2|de/f/ gB|A>G AB/c/|d/f/e/d/ BA|
BB/A/ G>B|de/f/ gB|AG/A/ BB/A/|G2 G2 :|

%%%

X:31144
T:OLD CROSSROADS (march) 
Z:ABC/arr. BB
B:JOL.332 (unnamed)
Q:1/4=120
L:1/8
M:C
R:march
K:Em
zD|E3F GFGA|B2e2 dA3|G>FGB AFDE|F2E2 DB,B,D|
E3F G2GA|B2e2 dA3|G3B AFDE|F2E2E2:|
d^c|B2B2 e2de|f2e2 d3B|A>GAB d3e|dBAB d2BA|
B2B2 e2de|f2e2 d3A|G3B AFDE|F2E2E2 :|

%%%

X:31176
T:PA KEANE'S POLKA 
Z:ABC/arr. BB
B:JOL.205
Q:1/4=120
L:1/8
%Kind of an odd tune that sounds like it should return 
%to the first part to close. The A-B-A structure is mine, 
%not the source's.
P:ABCA
%play_flatten_parts
M:2/4
R:polka
P:A
K:D
|:"^A"Ad cB|AF DE/D/|GF/G/ BA|FA DE/D/|
Ad cB|AF DE/F/|GE BA|D2 D2 :|
P:B
|:dc/d/ fa|ge ed/e/|A/B/c/d/ eg|fd dA|
dA/d/ fa|ge e/f/e/d/|cB ba|d2 d2 :|
P:C
K:A
A>G AF|FE EB/c/|d>c dB|c2 c/d/c/B/|
Ad fe/c/|Ac ec/B/|AB/c/ df|e2 e2|
ag af|e^d ec|Bc/B/ AF|E2 E2|
e^d/e/ fe|cA FA|EF A>B|A2-A=G||

%%%

X:31177
T:PADDY CRONIN'S SLIDE 
Z:ABC/arr. BB
B:JOL.075
Q:1/4=180
L:1/8
M:12/8
R:slide
K:D
D|E2G FED E2F G2A|BEE GFE BEE GFE|
D2F FED E2F G2A|B2E GFE F2E D2 :|
e|d3 c2d e2d cBA|B2E GFE BEE GFE|
d2d c2d e2d cBA|B2E GFE GFE D2 :|

%%%

X:31178
T:PADDY LYONS' JIG 
Z:ABC/arr. BB
B:JOL.003
Q:1/4=160
L:1/8
M:6/8
R:jig
K:Edor
E|BEE cBA|BEE ecA|BEE dcB|ADF d2F|
BEE cBA|BEE eBc|ded c2B|AFD D2 :|
F|E2e eAe|eEe efe|E2e eBc|dcB AFD|
E2e eEe|eEe efe|dcB c2B|AFD D2 :|
"^coda"F|E6|]

%%%

X:31179
T:PADDY SPILLANE'S POLKA (1) 
Z:ABC/arr. BB
B:JOL.049
Q:1/4=120
%simplified; source version here
L:1/8
M:2/4
R:polka
K:D
A|D2 FD/F/|AF D2|FD/F/ AF|FE EF/E/|
D2 FD/F/|AF DE/F/|GE CE|EDD :|
B|d>c dB|AF D2|FD/F/ AD|FE ED|
[1 d>c dB|AF DE/F/|GE CD|EDD :|
[2 Ad B2|AF DE/F/|GE CE|EDD2- |HD4|]

%%%

X:31180
T:PADDY SPILLANE'S POLKA (2) 
Z:ABC/arr. BB
B:JOL.050
Q:1/4=120
L:1/8
M:2/4
R:polka
K:D
A|D2 FD/F/|AF/A/ dF|AG GE|BA FA|
D2 FD/F/|AF/A/ dF|AG GE|EDD :|
z|Bc/B/ AF/A/|BA FD|BA AF/A/|dA FA|
DF/D/ FD/F/|AF/A/ dF|AG GE|EDD :|

%%%

X:31182
T:PADRAIG O'KEEFFE'S FAVORITE (slide)  
Z:ABC/arr. BB
B:JOL.086
Q:1/4=180
L:1/8
M:12/8
R:slide
K:Amaj
d|e3 efe dcd fed|c2A dBA a3 a2f |
e3 efe dcd fed|c2A BGB A3A2 :|
K:Amix
g|e2a aga e2d Bcd|e2a aga e2f d3 |
e2a a2g e2f gfe|d2e def g3 f2 :|
"^coda"g|a6z6|]

%%%

X:31181
T:PADRAIG O'KEEFFE'S SLIDE  
%aka Bill the Weaver's
Z:ABC/arr. BB
B:JOL.132
Q:1/4=180
L:1/8
M:12/8
R:slide
K:D
g| fed B2d A2d F2A|BAF D2F E2z g3 |
fed Bcd A2d F2A|BAF E2F D3- D2 :|
e|f3 a3 baf a2e|fdf a2d g3 bge|
fdf a3 baf a2e|fef a2f d3 d2e|
fef a2a baf a2e|fef afd g3 gfe|
fga efg fed Bcd|ABA GFE HD6 |]

%%%

X:31183
T:PAITÍ LEARY'S (jig)  
Z:ABC/arr. BB
B:JOL.117
Q:1/4=160
%simplified; source version here
L:1/8
M:6/8
R:jig
K:D
d/B/|AFF AdB|AFF F2E|DFD AFA|BEE EFG|
[1 AFA AdB|AFF F2A|dcd ede|fdc d2:|
[2 AFA AdB|AFA F2E|d2f ede|fdc d2 ||
|:B/c/|dfe d2B|BAB d2e|fdd add|fee efe|
[1 dfe d2B|A2A d2e|f>ef afd|efe d2:|
[2 dfe d2B|BAB d2e|fef afd|efe d3- |d6|]

%%%

X:31184
T:PEACOCK'S FEATHER (jig)   
Z:ABC/arr. BB
B:JOL.125
Q:1/4=160
L:1/8
M:6/8
R:jig
K:D
B|AFA DFE|DEF A2d|BGG dGG|BGG BAd|
AFA DFE|DEF A2B|def gfe|fdB BA :|
G|A2d fdd|edd fdd|Add fdd|edB BAF|
A2d fdf|ede fdd|faf g2e|1fdB BA :|
[2"^coda"fdB AGE|D6|]

%%%

X:31185
T:PEG WARREN'S (slide)  
Z:ABC/arr. BB
B:JOL.006
Q:1/4=180
L:1/8
M:12/8
R:slide
K:G
Bcd B2G D3 D3|Bcd B2G A3 A2B|
c2d ecA B2c d2B|ABc B2A G3 G3 :|
B2c d2B d3 d3|B2d d2B c3 c2A|
Bcd e2d B2c dcB|ABc B2A G3 G3 :|

%%%

X:31186
T:PETE BRADLEY'S POLKA  
Z:ABC/arr. BB
Q:1/4=120
L:1/8
M:2/4
R:polka
K:G
B2 B/c/B/A/|GE G/E/D|EA B/A/B/A/|GB d2|
B2 B/c/B/A/|GE G/E/D|EA B/A/B/A/|G2 G2 :|
Bd de|dB gB|dB gB|cA Ac/A/|
Bd de|dB/c/ gB|dB AB/A/|G2 G2 :|

%%%

X:31186
T:PETE BRADLEY'S SLIDE  
Z:ABC/arr. BB
B:JOL.023
Q:1/4=180
L:1/8
M:12/8
R:slide
K:D
e|f2a g2e fed B2A|def agf eAB cde|
faf gfe fed B2A|def efe d3 d2:|
K:A
f|e3 ece faa agf|efe efe dcd A2d|
e2e ece a2a agf|efe dcB A3 A2 :|

%%%

X:31188
T:PETTICOAT LOOSE (jig)  
Z:ABC/arr. BB
B:JOL.079
Q:1/4=160
%simplified version; source version here
L:1/8
M:6/8
R:jig
K:Ador
E|G2E cEE|GEE G2A|GEE cBc|Adc dcA|
GEE cBc|dcd eag|ege ded|cAA A2:|
d|efg efg|edB c2d|eag age|edc dcd|
efg efg|edB c2d|ege ded|cAA A2 :|

%%%

X:31189
T:PLANXTY CONNOR (slide) 
C:Carolan (!!)
Z:ABC/arr. BB
B:JOL.312
%" 'Tis another one of Bill the Weaver's old jigs." [JOL]
Q:1/4=180
M:12/8
L:1/8
R:slide
K:G
D|G2G FED E2F G2A|B2G c2A B2G c3|
Bcd EFG EAG FED|EFG AFD G3 G2 :|
F|G2G GBd e2f gfe|dBG GBd e2f gfe|
dBB cBA dBG FED|EFG AFD G3 G2 :|

%%%

X:31190
T:RAIN A SUP (slide) 
Z:ABC/arr. BB
B:JOL.047
Q:1/4=180
L:1/8
M:12/8
R:slide
K:G
c|d2B BAB c2B A2B|c2c cBc e2d B2c |
d2B BAB c2B A2B|ceB d2B G3 G2 :|
B/d/|g3-gfg aag fed|e3 ede faa def|
g3 gfg a2g fed|efg a2g fef g2 :|

%%%

X:31191
T:RED-HAIRED LASS (reel)  
Z:ABC/arr. BB
B:JOL.314
Q:1/4=180
M:4/4
L:1/8
R:reel
K:G
DGGF G2BA|G3B AGED|DGGF GABd|egdB cABG|
DGGF G2AF|G2BG AGED|DGGF GABd|gedB c3^c||
d2gd edgd|dagd BGB^c|d3g edef|gedB c2Bc|
d2gd edgd|dfgd BGBd|c2cd BcBA|\
G2Bd "^coda"efga|g8|]

%%%

X:31192
T:SAINT MARY'S POLKA 
Z:ABC/arr. BB
B:JOL.322
Q:1/4=120
L:1/8
M:2/4
R:polka
K:G
F|G2 AB/A/|Gg e/f/g/e/|dB AG/A/|B/c/B/A/ G/F/E/F/|
GB AB/A/|Gg e/f/g/e/|dB AG/A/|BG G :|
A|Bd g2|B/c/d gf/g/|Bd ge|f2 fg|
a2 e/f/g/e/|dB AG/A/|Bc/B/ d/B/A/B/|G2 G :|

%%%

X:31195
T:SCARTAGLEN JIG (slide)
Z:ABC/arr. BB
B:JOL.131
Q:1/4=180
L:1/8
M:12/8
R:slide
K:D
B|A2a aga Agf gfg|A2a aga efg efg |
[1 A2a aga A2g gfe|faf gfe d3 d2:|
[2 agf gfe fed edc|BAB gfe d3 d2||
|:A|c2A cee dff cee|c2A cee dcd fed|
cAA cec dfd cec|BAB gfe d3 d2 :|

%%%

X:31193
T:SCARTAGLEN POLKA (1) 
%aka Darby's Cross, Danny Green's
Z:ABC/arr. BB
B:JOL.041
Q:1/4=120
L:1/8
M:2/4
R:polka
K:D
B|AF AF/A/|BG BB|c/B/A/B/ ce|ed f/e/d/B/|
AF AF/A/|BG B2|c/B/A/B/ ce|edd :|
z|A2 g2|fe ee/d/|ef ga|ba f/g/a/f/|
ef gf/g/|fe e2|ef gc|edd :|

%%%

X:31194
T:SCARTAGLEN POLKA (2) 
T%aka Darby's Cross, Danny Green's
Z:ABC/arr. BB
B:JOL.110
Q:1/4=120
L:1/8
M:2/4
R:polka
K:D
B|AF AF/A/|BG B2|c/B/A/B/ ce|f/e/d B/c/d/B/|
AF AF/A/|BG B2|c/B/A/B/ ce|fdd :|
G|A2 g>g|fe e2|ef ga|ba a/g/a/f/|
ef g>g|fe ee/d/|ef gc|edd :|

%%%

X:31196
T:SHE DIDN'T DANCE AND DANCE (slide)  
T:Pete Sullivan's
Z:ABC/arr. BB
B:JOL.123
Q:1/4=180
L:1/8
M:12/8
R:slide
K:Edor
P:I
f|e2d BAB GAG G2A|B2d edB d3 g2f|
e2d BAB G2G G2f|efg fed e3g2 :|
P:II
A|Bcd e2f g2f gfg|Bdc d2e d3 B2A|
Bcd e2f g2f g2a|bag agf e3 e2d|
Bcd e2f g2f gfg|Bdc d2e d3 g2a|
bag agf gfe fed|efg fed He6|]

%%%

X:31197
T:SONNY SWEENEY'S (polka)  
Z:ABC/arr. BB
B:JOL.070
Q:1/4=120
L:1/8
M:2/4
R:polka
K:G
G/E/|D>E G>A|Bd BG/B/|AG/A/ BA|AG E/F/G/E/|
D>E G>A|Bd BG/B/|AG/A/ BB/A/|G2 G :|
f|g2 e/f/g/e/|dB dA|G>B AB|AG ED|
[1 gf/g/ e/f/g/e/|dB dA|G>B AB|AG G:|
[2 D>E G>A|Bd BG/B/|AG/A/ B>A|HG4|]

%%%

X:31198
T:SWEENEY'S POLKA 
Z:ABC/arr. BB
B:JOL.282
Q:1/4=120
L:1/8
M:2/4
R:polka
K:A
ef/e/ ce|Ae ce|f/g/a/f/ ec|BA FA|
ef/e/ ce|Ae ce|a>f ec|BA A2 :|
ce f/g/a/f/|ec BA|ce a>f|ec Bc/B/|
ce f/g/a/f/|ec BA|ef/e/ cB|cA A2 :|

%%%

X:31199
T:TAIDHGIN AN ASAIL'S JIG 
%aka Kitchen With No Food; Where's the Cat?
Z:ABC/arr. BB
Q:1/4=180
B:JOL.251
L:1/8
M:12/8
R:slide
K:G
z|DED G2D E2D G2G | DED G2B ABG E2D |
DED G2G E2D G3|Bcd c2B ABG E2 :|
A|B2c d2B AGE c3|BAB dcB ABG E2D|
BGB d2B AGE c3|"thru"g2e d2B ABG E2 :|
"^coda"F|G6z6|]

%%%

X:31200
T:TERRY LANE'S WALTZ 
Z:ABC/arr. BB
B:JOL.273
Q:1/4=180
L:1/8
M:3/4
R:waltz
K:D
dB|:A2 F2A2|d2c2B2|B2 A2 D2|F4FG|
A2G2 F2|E2C2E2|B2A2 D2|F4-FG|
A2F2 A2|d2czB2|B2 A2 D2|F4F2|
A2G2 F2|E2C2E2|D6|1 D4 FB:|2 D3-D||
%
|:ef|g4-gf|g2e2g2|f4-fg|f2 d2-df|
e2e2-ef|e2 c2 e2|d4de|d2e2f2|
g4-gf|g2 e2 g2|f4- fg|f2 d2-df|
e4-ef|e2c2e2|1 d4-de|d2e d:|2 d4-d||
%
|:G|A6|FA D2-DF|A,2D2-DB|B2A4|
A2g2-gf|e2-ed e2|A2f2e2|d2 F2G2|
A6|FA D2-DF|A,2D2-DB|B2A4|
A2g2 f2|e2c2e2|1 "thru"d6-|d2- dE F:|\
[2 "^coda"d2 f2  c2|Hd6|]

%%%

X:31201
T:THADE JANEY BUCKLEY'S (jig)   
Z:ABC/arr. BB
B:JOL.255
Q:1/4=160
L:1/8
M:6/8
R:jig
K:G % source key = A
A|BAG EGD|EGD EGA|BAG EGD|EAG AGA|
BAG E2D|EGD EGB|BAG EGD|EGF G2 :|
z|GBd e2d|egd B2A|GBd e2d|e2a aga|
bag agf|gfe dBA|BAG EGD|EGF G2 :|

%%%

X:31202
T:THADELO SULLIVAN'S POLKA  
Z:ABC/arr. BB
B:JOL.190
Q:1/4=120
L:1/8
M:2/4
R:polka
K:A
c/B/|:AG/A/ Bc/B/|AB/A/ fA/f/|e/c/B e/c/B|c/B/A ec/B/|
A2 Bc/B/|AB/A/ fA/f/|e/c/B e/c/B|c/B/A A2:|
a>f ef|ec BA|Bc ef|ec B/c/B/A/|
a>f ef|ec BA|Bc e/f/e/c/|BA A2 :|

%%%

X:31205
T:THADELO'S HORNPIPE (1) 
Z:ABC/arr. BB
B:JOL.112
Q:1/4=150
L:1/8
M:4/4
R:hornpipe
K:G % source key = A
%swing .25
GA|B2BA BAGA|BGEG D3A|GABG A2GA|BAAG A2G2|
[1 ABBA BAGA|BGEG D3A|G2 BG A2GA|BGGA G2:|
[2 BddB dBGA|BGEG D3B|G2 BG A2GA|BGGA G2||
|:GA|BddB d2d2|egg=f g2 ge|d2 de dBGA|BAAG A2G2|
BddB d2d2|egg=f g2 (3de=f|g2ge dBGA|BdAB G2:|

%%%

X:31206
T:THADELO'S HORNPIPE (2) 
Z:ABC/arr. BB
B:JOL.189 (as "Thadelo Sullivan's")
%Repeats not in source
Q:1/4=150
L:1/8
M:4/4
R:hornpipe
K:D
%swing .25
B|d2ef g2 fg|eged B4|dcdB A2 A2|dedB A4|
d2 ef g2 fg|eged B4|dcde dBAB|G4 G3:|
B|d2BA BABd|e2 A2 A4|d2BG AGA=c|B2 G2 G3e|
d2BA BABd|e2 A2 A4|dcde dBAB|G4 G3:|

%%%

X:31207
T:THADELO'S HORNPIPE (3) 
Z:ABC/arr. BB
B:JOL.246
Q:1/4=150
L:1/8
M:4/4
R:hornpipe
K:D
%swing .25
A3B AFDE|F2FE F2FG|A2AB AFDF|G2ED E3F |
GAGF GFEF|GAGF G2B2|A2AB AGFE|D4-D4 :|
|:f4 e2de|d2A2 A2dA|B2BA B2dB|c2A2 A4 |
f2gf e2fe|d2A2 A2dA|B2BA B2dA|e2d2 d2 :|

%%%

X:31203
T:THADELO'S POLKA 
Z:ABC/arr. BB
B:JOL.104
Q:1/4=120
L:1/8
M:2/4
R:polka
K:A
A|B>f ef|ec BA|Bc ef|ec BA|
af ef|ec BA|Bc e/f/e/c/|BAA :|
c/B/|AG/A/ Bc/B/|AB/A/ fe/f/|e/c/B e/c/B|c/B/A ec/B/|
A2 Bc/B/|AB/A/ fe/f/|e/c/B e/c/B|c/B/A A :|

%%%

X:31204
T:THADELO'S SLIDE 
Z:ABC/arr. BB
B:JOL.076
Q:1/4=180
L:1/8
M:12/8
R:slide
K:A
B|c3 cBA B2A F2A|BAB c2d e3 e2A|
BAB cBA B2A F3|1 A2B c2B A3 A2 :|
[2 A2B c2B A3 Ace|:f2e cBA B2A F3|
f2e c2d e3 ece|f2e cBA B2A F2A|
A2B c2B A3-A3 :|

%%%

X:31208
T:TIM SULLIVAN'S (hornpipe)  
Z:ABC/arr. BB
B:JOL.014
Q:1/4=150
L:1/8
M:4/4
R:hornpipe
K:A
%swing .25
af|e2 A2 c2 A2|cecB cecA|B2 ce f4|B2 ce f2 af|
e2 A2 c2 A2|(3cde cB cecA|B2 ce f2 ec|1 B2 A2 A2 :|\
[2(3BcB A2 A3||
|:d|e2 a2 g2 f2|e2 c2 (3cdc BA|B2 ce f2 f2|B2 ce f4|
e2 a2 g2 f2|e2 c2 (3cdc BA|B2 ce f2 ec|B2 A2 A3 :|

%%%

X:31209
T:TOM BILLY MURPHY'S (jig)  
Z:ABC/arr. BB
B:JOL.182
Q:1/4=160
L:1/8
M:6/8
R:jig
K:Em
d|: dBA G3|BAG Add|dBA GBA|GEE EDE|
dBA G2A|BAB Bge|dBA GBA|GEE E3 :|
g3 e2f|gfg e2f|gfg eag|faa def|
gfg aAA|gef gfe|dBA GBA|GEE E3 :|

%%%

X:31210
T:TOM BILLY'S (slide)  
Z:ABC/arr. BB
B:JOL.118
Q:1/4=180
L:1/8
M:12/8
R:slide
K:D
B|A2F AFF BGG BGG|AFF AFA BEE E2B|
AFF AFF BGG BGG|AFA B2c d3 c2 :|
A|d2d ded cBB cBB|AFF AFA BEE EDE|
d2d ded cBB cBB|AFA B2c d3 d2 :|

%%%

X:31211
T:TOM BILLY'S WALTZ 
Z:ABC/arr. BB
B:JOL.272
Q:1/4=150
N:++ in m.22 is | d' | in source; ** in m.23 is | c' |
L:1/8
P:ABA
%play_flatten_parts
M:3/4
R:waltz 
K:D
P:A
|:F2F3A | d2d3A | B2d2 (3BcB | A4-Af |e4de |
f2-faaf |e2d2B2 | A2 D3E |F2F3A |dzd3A |B2d2 (3BcB |
A4-Af |e2d2e2 |f2a2-af |e2B2c2 |1 d4 DE :|2 d2-defg ||
P:B
|:a2a2f2 | d2f2g2 |a2-adfg |a4b2 |a4 f2| d2a2"++"b2 |
a4"**"g2b2 |b4ba |b4g2 |e4d2 |c4d2 |e4f2 |
g2 f2g2 |1 b2a2g2 |f2-fe fa| f4fg :|2 b2a2f2 |d6 |d4"_DC"AG|]

%%%

X:31212
T:TOM FLEMING'S (jig)   
%aka Paddy Fahy's, "The Barn Owl"
Z:ABC/arr. BB
B:JOL.343
Q:1/4=160
L:1/8
M:6/8
R:jig
K:D
DFA d2e|dcA GFG|AFD =c3|ed^c AGA|
DFA ded|dcA GFG|Adc AGE|EDC D3 :|
d2c ded|cAG A2B|=cBc ed^c|Bec A2c|
dcd fed|cAG A2G|Adc AGE|EDC D3 :|

%%%

X:31213
T:TOM MORRISON'S FAVORITE (jig)   
Z:ABC/arr. BB
B:JOL.299
Q:1/4=160
L:1/8
M:6/8
R:jig
K:Ador
z|cBA GED|EDE A2B|cBc Adc|BAB GBd|
gfg ege|dBG Bcd|ecA GED|EDE A2:|
g|aea aed|cAA Aef|gBB gdc|BAB GAB|
c3 dcd|edc Bcd|ecA BED|EAG A2 :|

%%%

X:31214
T:TROOPER (slide)  
Z:Z: ABC/arr. BB
B:B: JOL.100
Q:1/4=180
%Coda is my idea!
L:1/8
M:12/8
%R:slide
K:G
d|ege dBA BEF G2A|BAB def gfg agf|
ege dBA BEF G2A|BAB dBd e3 e2 :|
f|e2e ede fag fed|eff efg a2a faf|
efe ede fag fed|BAB def g3 fa :|
"^coda"f|eff def g3 g3|]

%%%

X:31215
T:TUAR MÓR POLKA (1) 
Z:ABC/arr. BB
B:JOL.087
Q:1/4=120
L:1/8
M:2/4
R:polka
K:D
e2 dB|cA B/c/d|ef/e/ dB|c/B/A A2|
ef/e/ dB|c/B/A B/c/d|af/a/ ge/c/|ed d2 :|
f2 ga|B/c/d ef|g2 ge/g/|ba fa|
f>e fA|B/c/d ef|ab/a/ gc|ed d2 :|

%%%

X:31216
T:TUAR MÓR POLKA (2) 
%aka Back of the Haggard, Maid(s) of Ardagh
Z:ABC/arr. BB
B:JOL.088
Q:1/4=120
L:1/8
M:2/4
R:polka
K:D
E|FA BA|d>e f2|g/f/e/f/ gB|ed Bd|
FG/A/ BA|d>e f2 g/f/e/f/ gB|edd :|
K:A
z|ef/e/ ce|fe a2|e/f/g/e/ ce|fe cA|
e/f/g/e/ ce|fe a2|ef/e/ dB|c/B/A A :|

%%%

X:31217
T:TURKEY IN THE STRAW (hornpipe)  
Z:ABC/arr. BB
B:JOL.247
Q:1/4=150
L:1/8
M:4/4
R:hornpipe
K:D
%swing .25
fe|d2dc d2 FG|ABAF A2 de|f2 fe fede|feed e2 fe|
d2-dc d2 FG|ABAF A2 de|faag afde|fdec d2 :|
de|faag a2 a2|faag a2 a2|gbba b2 b2|gbba b4|
[dd']2 [d2d'2] a2 a2|fafd e2 de|faab afde|f2 e2 d2 :|

%%%

X:31218
T:WALSH'S HORNPIPE  
Z:ABC/arr. BB
B:JOL.119
Q:1/4=150
%simplified; source version here
L:1/8
M:4/4
R:hornpipe
K:A 
%swing .25
G|AcEF Acec|dfBc def2|(3fed ce aceA|BdcA BAFA|
(3ABc EF Acec|dfBc def2|(3fed ce aceA|B2cB A3 :|
e|aece fece|aece fecB|A2ce aecA|B2Bc BAFG|
AcEF Acec|dfBc def2|(3fed ce aceA|BdcB A3 :|

%%%

X:31219
T:WHEN THE COCK CROWS IT IS DAY (jig)   
T:Tá an Coileach ag Fogairt an Lae
Z:ABC/arr. BB
B:JOL.329
Q:1/4=160
L:1/8
M:6/8
R:jig
K:G
F|GBB BAG|d3 d2B|GBB BAG|A2A ABA|
GBB BAG|dBd ege|dBG AFD|G3 G2 :|
d|gdd gdB|c3 c3|gdd gdB|A2B ABd|
gdd gdd|c2c ege|dBG AFD|G3 G2 :|

%%%

X:31220
T:WHITE-HAIRED LASS (reel)  
%aka Ships Are Sailing
Z:ABC/arr. BB
Q:1/4=180
B:JOL.328
M:4/4
R:reel
K:Em
GA|Beed BAdB|AD (3FED ADFD|E3F GFGA|Bdef gfed|
B2ed BAdB|ADFD ADFD|E3F GFGA|Beed e2 :|
ef|:g2eg bgeg|fadf afdf|gfga bgeg|fadf e3f|
gfga bgeg|fadf afdf|g2bg f2af|edef gfed :|
"^coda"e4-e2z2|]

%%%

X:31221
T:WILLIE REIDY'S FAVORITE (slide)  
Z:ABC/arr. BB
B:JOL.336
%Elsewhere in JOL "Willie" is "Willy"!
Q:1/4=180
L:1/8
M:12/8
R:slide
K:G
A|B2G Bcd B2G Bcd|A2D ABc A2F A2c|
B2G Bcd B2G B2d|AFA DFA G3 G2 :|
f|g2g d2d gfg d3|f2f A2A fef A3|
g2g def g2a bag|fed cBA G3 G2 :|

%%%

X:31222
T:WILLY REIDY'S POLKA (1) 
Z:ABC/arr. BB
B:JOL.224
Q:1/4=120
L:1/8
M:2/4
R:polka
K:G
G/A/G/F/ GA|BG/B/ AB/c/|d2 cA|GF ED|
G>F GA|BG/B/ AB/c/|dd cB/A/|G2 G2 :|
d>e dc|Bc dB/d/|ed cB/c/|AG FD|
d>e dc|Bc dB/d/|dB cA|G2 G2 :|

%%%

X:31223
T:WILLY REIDY'S POLKA (2) 
Z:ABC/arr. BB
B:JOL.245
Q:1/4=120
L:1/8
M:2/4
R:polka
K:A 
ef/e/ ce|Bc/B/ Ac|Bc/B/ AB|cB Bc/B/|
ef/e/ ce/c/|Bc/B/ Ac|Bc/B/ AB|cA A2 :|
ce/f/ a2|gf f/g/f/e/|ce fg|fe c/e/c/B/|
ce ag/a/|gf f/g/f/e/|ce fg|a2 a2 :|

%%%

X:31224
T:YELLOW TINKER (reel) 
Z:ABC/arr. BB
B:JOL.153
%:This reel is mostly played in G modal, so I've 
%transposed the source version to that key.
Q:1/4=180
%simplified; source version here
M:4/4
L:1/8
R:reel
K:Gmix
P:I
FE|DGG2 DFF2|DGG2 dGAG|DGG2 DFF2|cAFA c2:|
P:II
ze|dGG2 dGAc|dggd fdce|dG G2 dcAB|cAFA c2Bc|
d2 BG dGBG|dgge fdce|g2de fgaf|b2ab gedc||
P:III
d2 BG BdBG|BdBG c2Bc|d2BG Acde|fdcA FAce|
d2 BG BdBG|BdBG c3e|dcde fefd|cAFA HG4|]

%%%

X:31225
T:YOUNG TIM MURPHY (jig) 
%aka Kitty Lie Over, What Would You Do. . . 
Z:ABC/arr. BB
Q:1/4=160
B:JOL.139
M:6/8
L:1/8
R:jig
K:D
P:I
B|A3 D2F|Add B2A|ABA F2D|GFG EFG|
ABA DFA|Add BAF|ABA F2E|FDD D2 :|
P:II
e|fef dBA|Bdc d2e|f2f def|gfg efg|
fed B2d|Add FAA|ABA F2E|FDD D2e|
fdd dBA|fdd d2e|faa def|gfg efg|
afd Bcd|Add FAA|ABA F2E|FDD HD3|]

%%%